encoding(3)

NAME
encoding - allows you to write your script in non-ascii or non-utf8

SYNOPSIS
  use encoding "greek";  # Perl like Greek to you?
  use encoding "euc-jp"; # Jperl!

  # or you can even do this if your shell supports your native encoding

  perl -Mencoding=latin2 -e '...' # Feeling centrally European?
  perl -Mencoding=euc-kr -e '...' # Or Korean?

  # more control

  # A simple euc-cn => utf-8 converter
  use encoding "euc-cn", STDOUT => "utf8";  while(<>){print};

  # "no encoding;" supported (but not scoped!)
  no encoding;

  # an alternate way, Filter
  use encoding "euc-jp", Filter=>1;
  use utf8;
  # now you can use kanji identifiers -- in euc-jp!

ABSTRACT
Let's start with a bit of history: Perl 5.6.0 introduced Unicode support. You could apply "substr()" and regexes even to complex CJK characters -- so long as the script was written in UTF-8. But back then, text editors that supported UTF-8 were still rare and many users instead chose to write scripts in legacy encodings, giving up a whole new feature of Perl 5.6.

Rewind to the future: starting from perl 5.8.0 with the encoding pragma, you can write your script in any encoding you like (so long as the "Encode" module supports it) and still enjoy Unicode support. You can write code in EUC-JP as follows:

  my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
               #<-char-><-char->   # 4 octets
  s/\bCamel\b/$Rakuda/;

And with "use encoding "euc-jp"" in effect, it is the same thing as the code in UTF-8:

  my $Rakuda = "\x{99F1}\x{99DD}"; # two Unicode Characters
  s/\bCamel\b/$Rakuda/;

The encoding pragma also modifies the filehandle disciplines of STDIN, STDOUT, and STDERR to the specified encoding. Therefore,

  use encoding "euc-jp";
  my $message = "Camel is the symbol of perl.\n";
  my $Rakuda = "\xF1\xD1\xF1\xCC"; # Camel in Kanji
  $message =~ s/\bCamel\b/$Rakuda/;
  print $message;

Will print "\xF1\xD1\xF1\xCC is the symbol of perl.\n", not "\x{99F1}\x{99DD} is the symbol of perl.\n".

You can override this by giving extra arguments; see below.

USAGE

use encoding [ENCNAME] ;
    Sets the script encoding to ENCNAME. Filehandle disciplines of STDIN and STDOUT are set to ":encoding(ENCNAME)". Note that STDERR will not be changed.

    If no encoding is specified, the environment variable PERL_ENCODING is consulted. If no encoding can be found, the error "Unknown encoding 'ENCNAME'" will be thrown.

    Note that non-STD file handles remain unaffected. Use "use open" or "binmode" to change disciplines of those.

use encoding ENCNAME [ STDIN => ENCNAME_IN ...] ;
    You can also individually set encodings of STDIN and STDOUT via the "STDIN => ENCNAME" form. In this case, you cannot omit the first ENCNAME. "STDIN => undef" turns the IO transcoding completely off.

no encoding;
    Unsets the script encoding. The disciplines of STDIN, STDOUT are reset to ":raw" (the default unprocessed raw stream of bytes).

CAVEATS

  NOT SCOPED
The pragma is a per script, not a per block lexical. Only the last "use encoding" or "no encoding" matters, and it affects the whole script. However, the <no encoding> pragma is supported and use encoding can appear as many times as you want in a given script. The multiple use of this pragma is discouraged.

Because of this nature, the use of this pragma inside the module is strongly discouraged (because the influence of this pragma lasts not only for the module but the script that uses). But if you have to, make sure you say "no encoding" at the end of the module so you contain the influence of the pragma within the module.

  DO NOT MIX MULTIPLE ENCODINGS
Notice that only literals (string or regular expression) having only legacy code points are affected: if you mix data like this

        \xDF\x{100}

the data is assumed to be in (Latin 1 and) Unicode, not in your native encoding. In other words, this will match in "greek":

        "\xDF" =~ /\x{3af}/

but this will not

        "\xDF\x{100}" =~ /\x{3af}\x{100}/

since the "\xDF" (ISO 8859-7 GREEK SMALL LETTER IOTA WITH TONOS) on the left will not be upgraded to "\x{3af}" (Unicode GREEK SMALL LETTER IOTA WITH TONOS) because of the "\x{100}" on the left. You should not be mixing your legacy data and Unicode in the same string.

This pragma also affects encoding of the 0x80..0xFF code point range: normally characters in that range are left as eight-bit bytes (unless they are combined with characters with code points 0x100 or larger, in which case all characters need to become UTF-8 encoded), but if the "encoding" pragma is present, even the 0x80..0xFF range always gets UTF-8 encoded.

After all, the best thing about this pragma is that you don't have to resort to \x{....} just to spell your name in a native encoding. So feel free to put your strings in your encoding in quotes and regexes.

Non-ASCII Identifiers and Filter option
The magic of "use encoding" is not applied to the names of identifiers. In order to make "${"\x{4eba}"}++" ($human++, where human is a single Han ideograph) work, you still need to write your script in UTF-8 or use a source filter.

In other words, the same restriction as with Jperl applies.

If you dare to experiment, however, you can try the Filter option.

use encoding ENCNAME Filter=>1;
    This turns the encoding pragma into a source filter. While the default approach just decodes interpolated literals (in qq() and qr()), this will apply a source filter to the entire source code. In this case, STDIN and STDOUT remain untouched.

What does this mean? Your source code behaves as if it is written in UTF-8. So even if your editor only supports Shift_JIS, for example, you can still try examples in Chapter 15 of "Programming Perl, 3rd Ed.". For instance, you can use UTF-8 identifiers.

This option is significantly slower and (as of this writing) non-ASCII identifiers are not very stable WITHOUT this option and with the source code written in UTF-8.

To make your script in legacy encoding work with minimum effort, do not use Filter=>1.

EXAMPLE - Greekperl
    use encoding "iso 8859-7";

    # \xDF in ISO 8859-7 (Greek) is \x{3af} in Unicode.

    $a = "\xDF";
    $b = "\x{100}";

    printf "%#x\n", ord($a); # will print 0x3af, not 0xdf

    $c = $a . $b;

    # $c will be "\x{3af}\x{100}", not "\x{df}\x{100}".

    # chr() is affected, and ...

    print "mega\n"  if ord(chr(0xdf)) == 0x3af;

    # ... ord() is affected by the encoding pragma ...

    print "tera\n" if ord(pack("C", 0xdf)) == 0x3af;

    # ... as are eq and cmp ...

    print "peta\n" if "\x{3af}" eq  pack("C", 0xdf);
    print "exa\n"  if "\x{3af}" cmp pack("C", 0xdf) == 0;

    # ... but pack/unpack C are not affected, in case you still
    # want to go back to your native encoding

    print "zetta\n" if unpack("C", (pack("C", 0xdf))) == 0xdf;

KNOWN PROBLEMS
For native multibyte encodings (either fixed or variable length), the current implementation of the regular expressions may introduce recoding errors for regular expression literals longer than 127 bytes.

The encoding pragma is not supported on EBCDIC platforms. (Porters who are willing and able to remove this limitation are welcome.)

SEE ALSO
perlunicode, Encode, open, Filter::Util::Call,

Ch. 15 of "Programming Perl (3rd Edition)" by Larry Wall, Tom Christiansen, Jon Orwant; O'Reilly & Associates; ISBN 0-596-00027-8